log using "mortality_confirmed_2006_5fcv.log", replace

***
* product: mortality_confirmed_2006_5fcv.dta
* generate dataset with FEM 10-year (2006-2016) cognitive&mortality status
* indata: FEM 2006-2016 simulation detailed output
* outdata: FEM 2006-2016
* cognitive & mortality status: AD/MCI/Normal/Dead w/o AD/Dead w/ AD
* exhibits: Table4 FEM; as dependent in: Table5
* dependent files: "../hrs/mortality_hrs_confirmed.dta"
***

local maxrep 500
local minyr 2006
local maxyr 2016

forvalues fold = 1/5 {
    forvalues rep = 1/`maxrep' {
        forvalues year=`minyr'(2)`maxyr' {
            append using ../../../output/5fcv`fold'/detailed_output/y`year'_rep`rep'.dta
        }
    }
}

drop if died==1&year==2006

merge m:1 hhidpn using "../hrs/mortality_hrs_confirmed.dta", keepusing(hhidpn confirmed_cogcat_hrs2006_nomi weight8)
keep if _m==3
rename confirmed_cogcat_hrs2006_nomi hrs_cogcat2006_nomi
rename weight8 weight_hrs8 

gen totcog_si = totcog - 1
gen cogcat = .
replace cogcat = 1 if totcog_si <= 6 
replace cogcat = 2 if totcog_si >= 7 & totcog_si <= 11
replace cogcat = 3 if totcog_si >= 12 & totcog_si <= 27
replace cogcat=. if died==1

egen newid = group(hhidpn mcrep)
gen wave = (year-1992)/2 + 1
xtset newid wave
gen l2cogcat = l.cogcat

gen confirmed_cogcat = .
replace confirmed_cogcat = 1 if (l2cogcat==1)&(cogcat==1)|(l2cogcat==1)&(died==1)
replace confirmed_cogcat = 2 if ((l2cogcat==2)&(cogcat==2))|((l2cogcat==2)&(cogcat==1))|((l2cogcat==1)&(cogcat==2))|((l2cogcat==2)&(died==1))
replace confirmed_cogcat = 3 if (l2cogcat==3)|(cogcat==3)
xtset, clear

gen prior_totcog = .
gen prior_cogcat = .
gen prior_cogstate = .
gen absorbing_cogcat = confirmed_cogcat
gen ad_absorbing_cogcat = confirmed_cogcat
keep hhidpn mcrep totcog_si cogcat cogstate year died weight confirmed_cogcat prior_totcog prior_cogcat prior_cogstate age hrs_cogcat2006_nomi weight_hrs8 absorbing_cogcat ad_absorbing_cogcat
reshape wide totcog_si cogcat cogstate died weight confirmed_cogcat prior_totcog prior_cogcat prior_cogstate age absorbing_cogcat ad_absorbing_cogcat, i(hhidpn mcrep) j(year)
drop if age2006<53

forvalues i=2006(2)2014 {
    local j =`i' + 2
    replace absorbing_cogcat`j' = absorbing_cogcat`i' if absorbing_cogcat`j'>absorbing_cogcat`i'|missing(absorbing_cogcat`j')
    replace ad_absorbing_cogcat`j'= 1 if ad_absorbing_cogcat`i'==1
}

gen dead_16=0
gen dead_w_de_16 = 0
gen dead_wo_de_16 = 0
gen dead_w_mci_or_worse_16 = 0
gen dead_w_missing_16 = 0
gen dead_w_de_16_ab = 0
gen dead_wo_de_16_ab = 0
gen dead_w_de_16_adab = 0
gen dead_wo_de_16_adab = 0

forvalues i=2006(2)2016 {
    replace dead_16 = dead_16 + 1 if died`i'==1 
    replace dead_w_de_16 = dead_w_de_16+1 if (died`i'==1&confirmed_cogcat`i'==1)
    replace dead_wo_de_16 = dead_wo_de_16+1 if (died`i'==1&(confirmed_cogcat`i'==2|confirmed_cogcat`i'==3))
    replace dead_w_mci_or_worse_16 = dead_w_mci_or_worse_16+1 if (died`i'==1&(confirmed_cogcat`i'==1|confirmed_cogcat`i'==2))
    replace dead_w_missing_16 = dead_w_missing_16 + 1 if (died`i'==1&missing(confirmed_cogcat`i'))
    /* absorbing */
    replace dead_w_de_16_ab = dead_w_de_16_ab+1 if (died`i'==1&absorbing_cogcat`i'==1)
    replace dead_wo_de_16_ab = dead_wo_de_16_ab+1 if (died`i'==1&(absorbing_cogcat`i'==2|absorbing_cogcat`i'==3))
    /* AD absorbing */
    replace dead_w_de_16_adab = dead_w_de_16_adab+1 if (died`i'==1&ad_absorbing_cogcat`i'==1)
    replace dead_wo_de_16_adab = dead_wo_de_16_adab+1 if (died`i'==1&(ad_absorbing_cogcat`i'==2|ad_absorbing_cogcat`i'==3))
}

gen status2016 = .
replace status2016 = confirmed_cogcat2016
replace status2016 = 4 if dead_wo_de_16==1&dead_16==1
replace status2016 = 5 if dead_w_de_16==1&dead_16==1

gen status2016_ab = .
replace status2016_ab = absorbing_cogcat2016
replace status2016_ab = 4 if dead_wo_de_16_ab==1&dead_16==1
replace status2016_ab = 5 if dead_w_de_16_ab==1&dead_16==1

gen status2016_adab = .
replace status2016_adab = ad_absorbing_cogcat2016
replace status2016_adab = 4 if dead_wo_de_16_adab==1&dead_16==1
replace status2016_adab = 5 if dead_w_de_16_adab==1&dead_16==1

save mortality_confirmed_2006_5fcv.dta, replace 


tab hrs_cogcat2006_nomi [aw=weight2006]
tab hrs_cogcat2006_nomi [aw=weight_hrs8]
tab hrs_cogcat2006_nomi status2016 [aw=weight2006], mi row
tab hrs_cogcat2006_nomi status2016 [aw=weight2006], mi cell
tab hrs_cogcat2006_nomi status2016_ab [aw=weight2006], mi row
tab hrs_cogcat2006_nomi status2016_ab [aw=weight2006], mi cell
tab hrs_cogcat2006_nomi status2016_adab [aw=weight2006], mi cell

log close