log using "two_year_decline.log", replace

***
* product: two_year_decline_5fcv.dta
* generate dataset for two-year decline ROC analysis
* indata: FEM simulation 2006-2016 detailed output; mortality_hrs_confirmed.dta
* outdata: data set for HRS and FEM two-year decline in TICS
* exhibits: Table6
* dependent files: "../hrs/mortality_hrs_confirmed.dta"
***

quietly include ../../../fem_env.do

local maxrep 500
local minyr 2006
local maxyr 2016

* read in and reshape fem data
forvalues fold = 1/5 {
    forvalues rep = 1/`maxrep' {
        forvalues year=`minyr'(2)`maxyr' {
            append using ../../../output/5fcv`fold'/detailed_output/y`year'_rep`rep'.dta
        }
    }
}

drop if died==1
gen totcog_si = totcog - 1
drop l2* died totcog
reshape wide age totcog_si cogstate adl1 adl1p adl2 adl3p adlstat iadl1 iadl2p iadlstat anyadl anyiadl hearte stroke cancre hibpe diabe lunge hearta smoken widowed smokev bmi qaly k6score, i(hhidpn mcrep) j(year)  

forvalues i=1/5 {
    local m = `i'*2 + 2004
    local n = `i'*2 + 2006
    gen fem_delta_rep`i' = totcog_si`n'-totcog_si`m'
}
keep hhidpn mcrep fem_delta_rep*  
tempfile fem
save `fem'

use "../hrs/mortality_hrs_confirmed.dta", clear
forvalues i=1/5 {
    local a = `i'+7
    local b = `i'+8
    gen hrs_delta`i' = totcog`b'-totcog`a'
    replace hrs_delta`i'=. if died`b'==1|missing(died`b')
}
keep hhidpn hrs_delta* totcog8 totcog9 totcog10 totcog11 totcog12 totcog13
tempfile hrs
save `hrs'

merge 1:m hhidpn using `fem'
keep if _m==3

keep hhidpn fem_delta_rep* hrs_delta* totcog8 totcog9 totcog10 totcog11 totcog12 totcog13

save two_year_decline_5fcv.dta, replace 

log close