log using "two_year_analysis.log", replace

***
* product: none
* generate ROC and PRC curve for two-year significant decline in TICS
* indata: two_year_decline_5fcv.dta
* outdata: none
* exhibits: Table6
* dependent files: two_year_decline_5fcv.dta
***

ssc install prtab

use "two_year_decline_5fcv.dta", clear

local decline_min 3
local decline_max 10



forvalues decline=`decline_min'(2)`decline_max' {
    local neg_decline = -`decline'
    forvalues i=1/5 {
        gen hrs_decline`i'_`decline' = (hrs_delta`i'<=`neg_decline')
        gen fem_decline`i'_`decline' = (fem_delta_rep`i'<=`neg_decline')
    }
}

collapse totcog8 totcog12 hrs_decline* fem_decline*, by(hhidpn)

*ROC and PRC

forvalues decline=`decline_min'(2)`decline_max' {
    forvalues i=1/5 {
        di "ROC year `i'; decline `decline'"
        roctab hrs_decline`i'_`decline' fem_decline`i'_`decline'
        roctab hrs_decline`i'_`decline' fem_decline`i'_`decline', graph saving(plots/roc/decline`i'_`decline', replace) title("ROC year `i' decline `decline'") scheme(s1mono)
        di "PRC year `i'; decline `decline'"
        prtab hrs_decline`i'_`decline' fem_decline`i'_`decline', interpolate saving(plots/prc/decline`i'_`decline', replace) title("PRC year `i' decline `decline'") scheme(s1mono)
        prtab hrs_decline`i'_`decline' fem_decline`i'_`decline', prec_at(0.05)
    }
}

clear

use "two_year_decline_5fcv.dta", clear
forvalues i=1/5 {
    bys hhidpn: egen fem_delta`i' = mean(fem_delta_rep`i')
}
bys hhidpn: keep if _n==_N

forvalues i=1/5 {
    local j = `i' + 7
    di "Pearson's correlation year `i'"
    pwcorr fem_delta`i' hrs_delta`i'
    di "Pearson's correlation year `i' - dementia last year"
    pwcorr fem_delta`i' hrs_delta`i' if totcog`j'<=6&!missing(totcog`j')
    di "Pearson's correlation year `i' - MCI last year"
    pwcorr fem_delta`i' hrs_delta`i' if totcog`j'>=7&totcog`j'<=11&!missing(totcog`j')
    di "Pearson's correlation year `i' - normal last year"
    pwcorr fem_delta`i' hrs_delta`i' if totcog`j'>=12&!missing(totcog`j')
    di "Pearson's correlation year `i' - dementia 2006"
    pwcorr fem_delta`i' hrs_delta`i' if totcog8<=6&!missing(totcog`j')
    di "Pearson's correlation year `i' - MCI 2006"
    pwcorr fem_delta`i' hrs_delta`i' if totcog8>=7&totcog8<=11&!missing(totcog`j')
    di "Pearson's correlation year `i' - normal 2006"
    pwcorr fem_delta`i' hrs_delta`i' if totcog8>=12&!missing(totcog`j')
}
log close