/** combine FEM and SSA e65 for plotting, save separate data sets for period and cohort e65 
*/

log using logs/fem_ssa_e65.log, replace

/*** load SSA data and transform to long ***/

use SSA_e65.dta

rename *, lower

rename e65type letype

reshape long male_ female_, i(calendar_year assumptions_year letype) j(cost) string
rename male_ e65_male
rename female_ e65_female
reshape long e65, i(calendar_year assumptions_year letype cost) j(sex) string

* high cost scenario is missing when assumptions year >= calendar year
drop if missing(e65)

gen rbyr = calendar_year - 65
*drop if rbyr < 1935 | rbyr > 1955
drop if rbyr < 1939 | rbyr > 1953

tostring assumptions_year, gen(yearc) 
gen series = "SSA " + yearc + " " + cost
drop yearc assumptions_year cost

gen male = sex == "_male"
drop sex

preserve
tempfile ssa_period_e65
keep if letype=="P"
save `ssa_period_e65'
li

restore
tempfile ssa_cohort_e65
keep if letype=="C"
drop calendar_year
save `ssa_cohort_e65'
li

/*** load and format FEM data for combining with SSA ***/

* scenarios for period e65
local periodscen mortval_cohort_nomortadj mortval_cohort_minimal_nomortadj
local nperscen : list sizeof periodscen

* scenarios for cohort e65
local cohortscen mortval_cohort_mortadj2016 mortval_cohort_minimal_mortadj2016 mortval_cohort_mortadj2004 mortval_cohort_minimal_mortadj2004
local ncohscen : list sizeof cohortscen

foreach letype in period cohort {
	foreach s in ``letype'scen' {
		local `letype'data ``letype'data' data/`s'_e65.dta
	}

	clear
	append using ``letype'data', gen(src)
	gen series = "FEM"
	gen scen = ""
	foreach s in ``letype'scen' {
		local pos : list posof "`s'" in `letype'scen
		append using `ssa_`letype'_e65'
		replace scen = "`s'" if ( missing(src) & missing(scen) ) | src==`pos'
	}
	
	drop letype src agedied n_died
	save data/fem_ssa_`letype'_e65.dta, replace

	sort male scen rbyr series
	li
}