***=======================================================*	 
* FEM scenario combination
* Mar 2008
* Incorpate adjustment factor for total medical spending and Medicaid spending
***=======================================================*	 

clear
set more off
set mem 500m

***=============================*	 

global outdata "//zeno/zeno_a/DOL/Output_Dec"
global tabdata "//zeno/zeno_a/DOL/Tables_Dec"


global scnr  "status_quo obese_r invobese_r shareprev nosmoke_r"
global scnr  "status_quo obs80 smk80"

#d;

global keepvar1  pop pop65p fracss62 fracss65 obese overwt diabe hearte hibpe ;
global keepvar2	 work ry_earn ssclaim
ttl_ssben ttl_diben ttl_ssiben
ttl_ftax ttl_stax ttl_ctax ttl_hoasi ttl_hmed ;
global keepvar3 ttl_caremd ttl_caidmd ttl_totmd mhhwealth mry_earnwork smokev smoken ttl_totmd;
#d cr

*********************************
* Adjustment factors
*********************************
local adj_totmd65l = 1.31
local adj_caremd65l = 1.59
local adj_caidmd65l = 2.53
local adj_totmd65p = 1.14
local adj_caremd65p = 1.11
local adj_caidmd65p = 1.64

foreach scr in $scnr {
	drop _all
	use "$outdata/51p_s`scr'_c.dta"
	gen pop65p = pop * (1 - dage5164)
	
	****************
	* Adjust for medical costs
	****************
	foreach v in totmd caremd caidmd {
		replace ttl_`v'l = ttl_`v'l * `adj_`v'65l'
		replace ttl_`v'p = ttl_`v'p * `adj_`v'65p'
		replace ttl_`v' = (ttl_`v'l + ttl_`v'p)/10^9
	}
	
	keep year $keepvar1 $keepvar2 $keepvar3
	keep if year == 2004 | year == 2006 | year == 2030 | year == 2050
	foreach v in $keepvar1 $keepvar2 $keepvar3 {
		ren `v' `v'_`scr'
	}	
	
	sort year, stable
	save temp_`scr'.dta, replace

	local sc `scr'_only
	#d;
	outsheet year pop* fracss* obese* overwt* diabe* hearte* hibpe* work* 
	ry_earn* ttl_ftax* ttl_stax* ttl_ctax* ttl_hoasi* ttl_hmed* ttl_ssben* 
	ttl_diben* ttl_ssiben* ttl_caremd* ttl_caidmd* ttl_totmd* mhhwealth* mry_earnwork* smokev* smoken* 
	using "$tabdata/scr_`sc'.csv", replace comma nol;
	#d cr
	
	if "`scr'" != "status_quo"{
	
	merge year using temp_status_quo.dta
	*erase temp_`scr'.dta
	drop _merge*
	
	foreach x in $keepvar1 $keepvar2 $keepvar3 {
			foreach s in `scr'{
			* replace `x'_`s' = (`x'_`s' - `x'_status_quo) * 100/ `x'_status_quo
			replace `x'_`s' = (`x'_`s' - `x'_status_quo)/ `x'_status_quo		
		}
	}
	drop *status_quo

	local sc `scr'
	#d;
	outsheet year pop* fracss* obese* overwt* diabe* hearte* hibpe* 
		work* ry_earn* ttl_ftax* ttl_stax* ttl_ctax* ttl_hoasi* ttl_hmed* 
		ttl_ssben* ttl_diben* ttl_ssiben* ttl_caremd* ttl_caidmd* ttl_totmd* mhhwealth* mry_earnwork* smokev* smoken* 
		using "$tabdata/scr_`sc'.csv", replace comma nol;
	#d cr

	}
}

foreach s in status_quo multi_r nosmoke_r obese_r invobese_r notrend {
	cap erase temp_`s'.dta
}

*XPOSE
	
foreach scr in $scnr {
	if "`scr'" != "status_quo" {
		drop _all
		local sc `scr'
		insheet using "$tabdata/scr_`sc'.csv"
		xpose, clear varname
		ren _varname scenario
		ren v1 yr2004
		ren v2 yr2006
		ren v3 yr2030
		ren v4 yr2050
		outsheet scenario yr2004 yr2006 yr2030 yr2050 using "$tabdata/scr_`sc'_x.csv", replace comma nol
		erase "$tabdata/scr_`sc'.csv"
	}
}
	
foreach scr in $scnr {
	drop _all
	local sc `scr'_only
	insheet using "$tabdata/scr_`sc'.csv"
	xpose, clear varname
	ren _varname scenario
	ren v1 yr2004
	ren v2 yr2006
	ren v3 yr2030
	ren v4 yr2050
	outsheet scenario yr2004 yr2006 yr2030 yr2050 using "$tabdata/scr_`sc'_x.csv", replace comma nol
	erase "$tabdata/scr_`sc'.csv"

}