/* 
This is a quick way to append the PSID (bootstrapped) and the HRS (bootstrapped).  It assumes that both the PSID and HRS have been bootstrapped.

To do: Ideally, we would not store these files this way.  Instead, we should use frequency weights on the file to represent the number of times an 
hhidpn appears in a given boostrap rep
*/

include common.do

* Define paths

local bsamp : env BREP

use $outdata/input_rep`bsamp'/psid_transition.dta


gen source = "psid"

append using $outdata/input_rep`bsamp'/hrs113_transition.dta

drop if wave < 5 & source != "psid"
replace aged = age_iwe if source != "psid"
replace l2aged = l2age_iwe if source != "psid"
tab source, m

* Generate age dummy variables
local age_var aged

replace hsless = educ_fam == 1 if source != "psid"
replace college = educ_fam == 3 if source != "psid"


	replace l2age35l = min(33,l2`age_var') if l2`age_var' < .
	replace l2age3544 = min(max(0,l2`age_var'-33),43-33) if l2`age_var' < .
	replace l2age4554 = min(max(0,l2`age_var'-43),53-43) if l2`age_var' < .
	replace l2age5564 = min(max(0,l2`age_var'-53),63-53) if l2`age_var' < .	
*	replace l2age65l  = min(63,l2`age_var') if l2`age_var' < .
	replace l2age6574 = min(max(0,l2`age_var'-63),73-63) if l2`age_var' < .
	replace l2age75p = max(0, l2`age_var'-73) if l2`age_var' < . 
	
	* Interact age splines with race
foreach var in black hispan male {
	replace l2age35l_`var' = l2age35l*`var' if l2age35l_`var' == .
	replace l2age3544_`var' = l2age3544*`var' if l2age3544_`var' == .
	replace l2age4554_`var' = l2age4554*`var' if l2age4554_`var' == .
	replace l2age5564_`var' = l2age5564*`var' if l2age5564_`var' == .
	replace l2age65l_`var' = l2age65l*`var'  if  l2age65l_`var' == . 
	replace l2age6574_`var' = l2age6574*`var' if l2age6574_`var' == .
	replace l2age75p_`var'  = l2age75p*`var' if  l2age75p_`var' == .
}


replace over65 = (l2`age_var' >= 63) if l2`age_var' < .

foreach var of varlist cancre diabe hearte hibpe lunge stroke smoken smokev {
	replace over65_l2`var' = over65 * l2`var'
}

drop male_hsless
gen male_hsless = male*hsless
label var male_hsless "Male, less than high school"

drop male_college
gen male_college = male*college
label var male_college "Male, college or more"

drop if l2age == 999

* Standardize measure
* annualize HRS measure
replace l2bingeannual = 4*l2binge if missing(source)

* Weekly binge
drop l2binge_3permo
gen l2binge_3permo = (l2bingeannual >= 36) if !missing(l2bingeannual)

save $outdata/input_rep`bsamp'/psid_hrs_transition.dta, replace