/** \file transition_select_biomarker.do

add biomarkers to data for transition estimation
*/

include common.do

use "$outdata/hrs113_transition.dta", clear

* Merge with biomarker files                                         
#d ;

drop sysbp l2sysbp;

merge 1:1 hhidpn wave using "$dua_rand_hrs/bio_hrs_recoded_impfinal.dta", keepusing(hhidpn wave biowgtr ldl_imp ldl_miss l2ldl_imp l2ldl_miss
                                                                                hdl_imp hdl_miss l2hdl_imp l2hdl_miss tchol_imp tchol_miss l2tchol_imp l2tchol_miss
                                                                                a1c_imp a1c_miss l2a1c_imp l2a1c_miss sysbp_imp sysbp_miss l2sysbp_imp l2sysbp_miss                                            
                                                                                logcrp_imp crp_miss l2logcrp_imp l2crp_miss crp_imp l2crp_imp
                                                                                ) keep (master match) nogen

	;
#d cr

foreach v in ldl hdl tchol a1c sysbp crp logcrp {
rename `v'_imp `v'
rename l2`v'_imp l2`v'
}

** Create the 2-year lag (L2) for those dummies - Now we use L2 biomarkers for transition models
** Imputed biomarkers 

  gen l2ldl100pl = (l2ldl> 100)
	replace l2ldl100pl = . if l2ldl == .

	gen l2tchol200240 = (l2tchol >=200 & l2tchol <240)
	gen l2tchol240pl = (l2tchol >=240)
	foreach var of varlist l2tchol200240 l2tchol240pl {
	replace `var' = . if l2tchol == .
	}

	gen l2hdl4060 = (l2hdl >=40 & l2hdl < 60)
	gen l2hdl60pl = (l2hdl >=60)
	foreach var of varlist l2hdl4060 l2hdl60pl {
	replace `var' = . if l2hdl == .
	}

	gen l2sysbp120140 = (l2sysbp >=120 & l2sysbp < 140)
	gen l2sysbp140160 = (l2sysbp >=140 & l2sysbp < 160)
	gen l2sysbp160pl = (l2sysbp >=160)
	foreach var of varlist l2sysbp120140 l2sysbp140160 l2sysbp160pl {
	replace `var' = . if l2sysbp == .
	}

	gen l2a1c5765 = (l2a1c >=5.7 & l2a1c < 6.5)
	gen l2a1c65pl = (l2a1c >=6.5)
	foreach var of varlist l2a1c5765 l2a1c65pl {
	replace `var' = . if l2a1c == .
	}
	
	gen l2crp3pl = (l2crp >3)
	foreach var of varlist l2crp3pl {
	replace `var' = . if l2crp == .
	}

** Interactions between 2-year lag of biomarkers and 2-year lag of treatment
gen l2ldl100pl_l2heartae = l2ldl100pl*l2heartae

gen l2ldl_l2rxchol = l2ldl*l2rxchol
gen l2hdl_l2rxchol = l2hdl*l2rxchol
gen l2tchol_l2rxchol = l2tchol*l2rxchol
gen l2sysbp_l2hibperx = l2sysbp*l2hibperx
gen l2a1c_l2diaberx = l2a1c*l2diaberx


gen l2hearte_l2rxchol = l2rxchol*l2hearte
gen l2stroke_l2rxchol = l2rxchol*l2stroke

***************************************
* Save data for transition model
***************************************
local fname = "$dua_rand_hrs/hrs$firstwave$lastwave" + "r_transition_bio.dta"
save `fname', replace